原文：Flash Remoting for Rails Tutorial

里克：1、Flash Remoting从flash player6就开始了，Flex Client是个新家伙。2、Flash Remoting如何翻译？我想翻译为flash远程。

在我们使用Rails的时候，可能会忽视掉另一个开发工具：Flash Remoting。长期的使用xml，可能会改变你的编程习惯。就像作者引用的那句话："If all you have is a hammer everything looks like a nail"。Remoting可以直接向flash传递对象，数组。Remoting使用AMF(Active Message Format)传递byte流，这比使用xml要快很多。

而且在06年8月，Midnight Coders发布了他们的WebORB插件。

他们的例子是基于Flex2的，这需要客户端安装Flash player9.0，这并不有好，因为Remoting在Flash player6中就已经开始使用了。所以这里我们只拿我们需要的。

如果你之前没有使用过Flash Remoting，请先安装Remoting Components。

这里我们制作一个flash的mp3播放器，用rails作为后端服务。点击这里，你可以下载这个例子的代码。

创建一个应用：mp3app

 
> rails mp3app
> cd mp3app

安装weborb插件

 
> ruby script/plugin install http://themidnightcoders.net:8089/svn/weborb

创建一个名为‘mp3app_development’的数据库

 
CREATE TABLE `tracks` (
  `id` int(11) NOT NULL auto_increment,
  `title` varchar(50) NOT NULL default '',
  `artist` varchar(50) NOT NULL default '',
  `album_art` varchar(50) NOT NULL default '',
  `filename` varchar(50) NOT NULL default '',
  PRIMARY KEY  (`id`)
) ENGINE=MyISAM DEFAULT CHARSET=latin1;
 
insert into `tracks` values
('1','After Midnight','Eric Clapton','clapton.jpg','AfterMidnight.mp3'),
 ('2','Midnight Train to Georgia','Gladys Knight','gladys.jpg',
'MidnightTrainToGeorgia.mp3'),
 ('3','Midnight In A Perfect World','DJ Shadow','shadow.jpg',
'MidnightInAPerfectWorld.mp3'),
 ('4','Two Minutes to Midnight','Iron Maiden','maiden.jpg',
'TwoMinutesToMidnight.mp3');

创建‘Track’model

 
> ruby script/generate model Track

在‘app/services’目录下创建一个Remoting services服务，文件为：'TrackService.rb'

 
require 'weborb/context'
require 'rbconfig'
 
class TrackService
   def getTracks
     tracks = Track.find(:all)
   end
end

如果你曾经用过AMFPHP或者.net下的Remoting，上面的这个服务端可以说是“相当”简单了。但是你可以运行测试一下。

下面进入到我们的Flash。
对于Flash应用，有几个框架可供选择，比如ARP和 Cairngorn。但是在我们这个应用上，他们显得太过强大了。我们可以写一个自己的轻量级的框架。这是一种MVC框架，Model是一个Remoting Class，用来和后台程序沟通(PHP, .NET, 或者 我们的 Rails) ，一个.fla的controller，和一个View class。
M 和 V 在 C 的控制下进行事件相应与处理，而其他的类来扩展其他的功能。

基本的Remoting是这样：

 
import mx.remoting.Service;
import mx.services.Log;
import mx.remoting.PendingCall;;
import mx.rpc.RelayResponder;
import mx.rpc.FaultEvent;
import mx.rpc.ResultEvent;
import mx.remoting.debug.NetDebug;
import mx.utils.Delegate;
 
class com.vixiom.remoting.Remoting
{
    private var gatewayURL:String;
    private var servicePath:String;
 
    private var svc:Service;
 
    function dispatchEvent() {};
    function addEventListener() {};
    function removeEventListener() {};
 
    /**
    * Constructor
    *
    *   @param      gURL    gatewayURL
    *   @param      sp      service path
    *   @param      u       username
    *   @param      p       password
    *
    */
    public function Remoting(gURL, sp, u, p)
    {
        gatewayURL = gURL;
        servicePath = sp;
 
        // initialize as a broadcaster
        mx.events.EventDispatcher.initialize(this);
 
        // create a new service
        svc = new Service (gatewayURL, null, servicePath, null, null);
 
        // credentials
        if (u != undefined && p != undefined) {
            svc.connection.setCredentials(u, p);
        }
 
    }
 
    /**
    * Global fault event
    */
    function handleRemotingError(fault:FaultEvent):Void
    {
        mx.remoting.debug.NetDebug.trace({level:"None",
        message:"Error: " +
        fault.fault.faultstring });
    }
 
    /**
    * Event dispatcher
    *
    *   @param      d       data
    *   @param      et      eventType
    *
    */
    function dispatch(d, et)
    {
        // broadcast message
        var eventObj:Object={target:this,type:et}
        eventObj.data = d;
        dispatchEvent(eventObj);
    }
 
}

基本的View Class是这样：

 
import mx.utils.Delegate;
 
class com.vixiom.view.View
{
    private var target:MovieClip;
 
    function dispatchEvent() {};
    function addEventListener() {};
    function removeEventListener() {};
 
    /**
    * Constructor
    *
    *   @param  t   target (target timeline: _root || a mc)
    */
    public function View (t:MovieClip)
    {
        target = t;
 
        // initialize as a broadcaster
        mx.events.EventDispatcher.initialize(this);
    }
 
    /**
    * Event dispatcher
    *
    *   @param      d       data
    *   @param      et      eventType
    *
    */
    function dispatch(d, et)
    {
        // broadcast message
        var eventObj:Object={target:this,type:et}
        eventObj.data = d;
        dispatchEvent(eventObj);
    }
}

里克：看到这个时候，我看了一下源代码。as文件的存放是按照类似java的形式。所以下面的话就好理解了。我对as的知识为0.

在这个MP3 player中，我用下面的方法扩充一下Remoting class。你可以不必把你的类放到这个packages里面，当然那样做更利于管理。

'var pc:PendingCall = this.svc.getTracks();'

一句是再远程调用Rails，这和TrackService.rb 类里面的'getTracks'是一样的。我的类中有一个tracks对象，它直接接收ruby的'tracks = re.result;'。我注释了'this.svc.connection.setCredentials(u, p);'一行，因为它在创建一个安全的远程调用。最后一行'dispatch(tracks, "onGetTracks");' 将数据传递给view。

 
import mx.remoting.*;
import mx.rpc.*;
 
class com.vixiom.remoting.RemotingMp3
extends com.vixiom.remoting.Remoting
{
    // tracks holder object
    private var tracks:Object;
 
    ////////////////////////////////////////////////////////////////
    //
    // Constructor (gatewayURL, servicePath, userid, password)
    //
    ////////////////////////////////////////////////////////////////
 
    public function RemotingMp3 (gURL, sp, u, p)
    {
        super(gURL, sp);
        // this.svc.connection.setCredentials(u, p);
    }
 
    ////////////////////////////////////////////////////////////////
    //
    // Get tracks with handler (onGetTracks)
    //
    ////////////////////////////////////////////////////////////////
 
    public function getTracks()
    {
        trace("// getting tracks")
        // create a pending call out to rails
        var pc:PendingCall = this.svc.getTracks();
        // create a responder to handle the return from rails
        pc.responder = new RelayResponder(this,
        "onGetTracks",
        "handleRemotingError");
    }
 
    public function onGetTracks (re:ResultEvent)
    {
        if (re != undefined)
        {
            trace("// onGetTracks broadcaster - Word!")
            // put result in recordset
            tracks = re.result;
            // trace for testing
            for (var i = 0; i < tracks.length; i++) {
                trace(tracks[i].title);
            }
            // dispatch event to the view
            dispatch(tracks, "onGetTracks");
        }
    }
}

下面是controller的代码，需要注意的是，‘Rmp3’是我扩展的Remoting class的实例。它有两个参数，一个是WebORB geteway url，一个是在app/services中的'TrackService'类。我还没有展示扩展的view class，controller里已经产生了一个‘Vmp3’实例，with the _root of the Flash file as it's parameter (it uses that as a target). 。下面四行是view中的按钮方法，最后一行调用远程方法，这是这个app的entry point(as it's pretty useless sans data)。

 
// import remoting, view, and debug
import mx.remoting.debug.NetDebug;
import mx.utils.Delegate;
import com.vixiom.remoting.RemotingMp3;
import com.vixiom.view.ViewMp3;
 
// ini debug
NetDebug.initialize ();
 
iniApp();
 
// setup and start
function iniApp()
{
    // create remoting & view objects
    var Rmp3:RemotingMp3    = new RemotingMp3 (
    "http://localhost:3000/weborb",
    "TrackService"); // weborb gateway, ruby class name
    var Vmp3:ViewMp3        = new ViewMp3 (_root);
 
    // set up listeners
    Rmp3.addEventListener ("onGetTracks",
    Delegate.create (Vmp3, Vmp3.onGetTracks));
 
    pause_btn.onRelease = Delegate.create(Vmp3, Vmp3.pauseTrack);
    play_btn.onRelease  = Delegate.create(Vmp3, Vmp3.playTrack);
    prev_btn.onRelease  = Delegate.create(Vmp3, Vmp3.previousTrack);
    next_btn.onRelease  = Delegate.create(Vmp3, Vmp3.nextTrack);
 
    // start the app, get the tracks
    Rmp3.getTracks();
}

下面是扩展的view，相当复杂，而且和rails及Remoting没什么关系，所以看一下它的注释，就能明白它的意思了。里克：我就不贴了，看类名就知道它在哪了。

 
class com.vixiom.view.ViewMp3 extends com.vixiom.view.View

就是这样了，不过要注意一下跨域安全问题，尤其是当你的rails应用在一台服务器上，而Flash文件在另一台服务器上的时候。

里克，07年10月23日，Railser.cn

前面写过一个简单的博文，介绍了一下flex与rails结合的进展。今天看到另一个好消息，《Flexible Rails：Flex 3 on Rails 2》一书将要问世了。作者：Peter Armstrong。目前网上已经可以买到PDF版本。

只要看看这本书的目录部分，喜欢flex和rails的朋友就会感到兴奋：

1. Why are we here? Where are we going?
2. Hello World
3. Getting started
4. Creating the Main Flex UI
5. Expanding the Rails code
6. Flex on Rails
7. Validation
8. Refactoring to RESTful Rails development
9. Refactoring to Cairngorm
10. Holding State on the client properly
11. Finishing the application
12. Rails on AIR (Adobe Integrated Runtime)

Appendix A. How to use Subversion with Flex and Rails
Appendix B. Handwaving at omitted topics

下载本书试读pdf 下载本书源代码

很想趁着人民币升值的时候买一本仔细看看，不过在花钱之前，我们还是可以看看其他网站的一些关于flex和rails的介绍。

WebORB for Ruby on Rails

WebORB是连接远程flash/flex客户端和Ruby on Rails应用的服务器端技术。WebORB可以以插件形式安装在任何Rails应用中，以提供Ruby类进行远程服务。WebORB提供完整的adobe AMF0和AMF3通信协议支持远程flash和flex客户端。

Rails安装WebORB插件，flex客户端如同请求Data Services server一样访问该插件（当前版本仅支持RPC子系统），远程flash应用连接WebORB和连接flash远程入口方法也是一样的。该插件接收和处理来自flex或者flash客户端的远程请求，然后调用部署在rails应用中的ruby类。

下一篇博文会对教程进行笔记。

不过有一个疑惑，什么是AMF3？

Flash 5开始就可以以XML或者“变量/值”配对输出格式向服务器传送数据。虽然这些数据能通过Flash编译器自动解析或者通过开发人员自行编写的代码手动解析, 但解析的速度慢。因为在解析过程中，XML需要按节点逐层处理数据。而且使用XML和“变量/值”配对格式处理的数据类型只能是字符型，数字也不例外。而 Flash Remoting却能处理复杂数据类型, 比如对象、结构、数组，甚至可以是数据集，配合DataGrid组件可以很方便地显示数据。

为了处理复杂数据类型，采用一种独有的方式使Flash与应用服务器间可以来回传送数据势在必行。于是AMF应运而生。AMF是Adobe独家开发出来的通信协议，它采用二进制压缩，序列化、反序列化、传输数据，从而为Flash 播放器与Flash Remoting网关通信提供了一种轻量级的、高效能的通信方式。如下图所示。

AMF最大的特色在于可直接将Flash内置对象，例如Object, Array, Date, XML，传回服务器端，并且在服务器端自动进行解析成适当的对象，这就减轻了开发人员繁复工作，同时也更省了开发时间。由于AMF采用二进制编码，这种方式可以高度压缩数据，因此非常适合用来传递大量的资料。数据量越大，Flash Remoting的传输效能就越高，远远超过Web Service。至于XML, LoadVars和loadVariables() ，它们使用纯文本的传输方式，效能就更不能与Flash Remoting相提并论了。

注意：Flash Remoting需要浏览器支持Binary POST，Flash 播放器在Netscape 6.x.环境下运行Flash Remoting会不起作用（Flash Remoting调用没有效果也不返回错误）， Netscape 7已经纠正了这个bug 。对于早期Safari和Chimera版的苹果机也有这个问题。

同样是轻量级数据交换协议，同样是通过调用远程服务，同样是基于标准的HTTP和HTTPS协议， Flash Remoting为什么选择了使用AMF而放弃了SOAP与Flash 播放器通信呢? 有如下原因：

1. SOAP将数据处理成XML格式，相对于二进制的AFM太冗长了；
2. AMF能更有效序列化数据；因为AMF的初衷只是为了支持Flash ActionScript的数据类型，而SOAP却致力于提供更广泛的用途；
3. AMF支持Flash 播放器 6只需要浏览器增加4 KB左右（压缩后）的大小，而SOAP就大多了；
4. SOAP 的一些头部文件请求在Flash 播放器 6不支持。那Flash 播放器 6为什么能访问基于SOAP的Web服务呢？原来Flash Remoting网关将SOAP请求在服务器端与转换成AFM格式，然后利用AFM与Flash 播放器通信。另外，AMF包中包含onResult事件（比如说response事件）和onStatus事件（比如说error事件），这些事件对象在 Flash中可以直接使用。

AMF从Flash MX时代的AMF0发展到现在的AMF3。AMF3用作Flash Playe 9的ActionScript 3.0的默认序列化格式，而AMF0则用作旧版的ActionScript 1.0和2.0的序列化格式。在网络传输数据方面，AMF3比AMF0更有效率。AMF3能将int和uint对象作为整数（integer）传输，并且能序列化 ActionScript 3.0才支持的数据类型, 比如ByteArray，XML和Iexternalizable。[里克：摘自网上，作者不详]

Ruby AMF

参考网站最后是网站地址
RubyAMF是开源的flash远程应用网关/方法(英文:gateway)。其RubyamfLite是独立的应用服务，可不依赖rails。RubyamfRails为rails插件，可以对rails controller的flash远程调用进行REST形式的AMF response。

---------------------------------------------------Railser.cn，07年10月20日编辑
参考网站：

Flexible Rails

flexonrails.net

WebORB for Ruby on Rails

AMF3 Specification

Ruby AMF